configure.in.in

# -*- autoconf -*-
# 
#
AC_INIT([lifev], [0.5.0], [lifev-dev@webmail.mate.polimi.it])

LIFEV_MAJOR_VERSION=0
LIFEV_MINOR_VERSION=5
LIFEV_MICRO_VERSION=0
LIFEV_EXTRA_VERSION=
AC_SUBST(LIFEV_MAJOR_VERSION)
AC_SUBST(LIFEV_MINOR_VERSION)
AC_SUBST(LIFEV_MICRO_VERSION)
AC_SUBST(LIFEV_EXTRA_VERSION)

LIFEV_PACKAGE=lifev
LIFEV_VERSION=${LIFEV_MAJOR_VERSION}.${LIFEV_MINOR_VERSION}.${LIFEV_MICRO_VERSION}${LIFEV_EXTRA_VERSION}



PACKAGE=$LIFEV_PACKAGE
VERSION=$LIFEV_VERSION

AC_SUBST(LIFEV_PACKAGE)
AC_SUBST(LIFEV_VERSION)



AC_CONFIG_AUX_DIR(admin)

dnl What the current system and host
AC_CANONICAL_HOST
AC_CANONICAL_SYSTEM


AM_INIT_AUTOMAKE([foreign check-news 1.7.8 dist-bzip2])
AM_CONFIG_HEADER(lifeconfig.h)

# checks for a C compiler
AC_PROG_CC( gcc-3.3 gcc-3.2 gcc )
AC_PROG_CC_C_O
AC_PROG_CXX( g++-3.3 g++-3.2 g++ )
AC_PROG_F77( g77-3.3 g77-3.2 g77 )
AC_PROG_F77_C_O

# no need for static libs 
AC_DISABLE_STATIC
AC_PROG_LIBTOOL

# pdflatex
AC_CHECK_PROG(PDFLATEX, pdflatex,[pdflatex],[no])

# doxygen
AC_CHECK_PROG(DOXYGEN, doxygen, [doxygen], [no-doxygen] )
AC_CHECK_PROG(LIFE_HAS_DOT, dot, [yes] )


dnl Check debugging mode for compilation.
AC_ARG_ENABLE(debug,
  AC_HELP_STRING([--enable-debug],[enables debugging mode (default=no)]),
  [
   if test $enableval = "no";
     then ac_use_debug_code="no"
     else ac_use_debug_code="yes"
   fi
  ], [ac_use_debug_code="no"])

AC_ARG_ENABLE(opt,
  AC_HELP_STRING([--enable-opt],[enables optimization mode (default=no)]),
  [
   if test $enableval = "no";
     then ac_use_opt_code="no"
     else ac_use_opt_code="yes"
   fi
  ], [ac_use_opt_code="no"])

if test $ac_use_debug_code = "yes" -a $ac_use_opt_code = "yes"
then
  AC_MSG_ERROR(Cannot use --enable-debug and --enable-opt at the same time!)
fi

#CXXFLAGS="-Wall -Wno-long-long -ansi -pedantic"
#CXXFLAGS="-Wall -Wno-long-long  -pedantic"
CXXFLAGS="-Wall -Wno-long-long"

if test $ac_use_debug_code = "yes"; then
 CPPFLAGS="-DLIFEV_CHECK_ALL ${CPPFLAGS}" 
 CXXFLAGS="-g3 -O0  ${CXXFLAGS}"
 CFLAGS="-g3 -O0  ${CFLAGS}"
else 
 if test $ac_use_opt_code = "yes"; then
  CXXFLAGS="-O2 -funroll-all-loops -fargument-noalias-global -fno-gcse ${CXXFLAGS}"
  CFLAGS="-O2 -funroll-all-loops -fargument-noalias-global -fno-gcse  ${CFLAGS}"
  CPPFLAGS="-DNDEBUG ${CPPFLAGS}"
 fi
fi

AC_CHECK_BOOST
AC_CHECK_BOOST_GRAPH
AC_CHECK_BOOST_SIGNALS
AC_CHECK_BOOST_TEST


dnl
dnl checks for some scientific computing libraries
dnl 
dnl libm
AC_CHECK_LIB(m,cos,[LIBS="-lm ${LIBS}"],${LIBS})
dnl umfpack
# disable it for not since it is not used yet: need to check for "NO"
# AC_CHECK_UMFPACK(4.3.0) # at least umfpack 4.3
AM_CONDITIONAL(HAVE_UMFPACK, test "x$umfpack_libs" != "x" )

dnl lapack, blas, g2c
AC_CHECK_LAPACK
AC_CHECK_UMFPACK

dnl aztec
AC_CHECK_AZTEC
dnl petsc
AC_CHECK_PETSC(2.1.6) #
AM_CONDITIONAL(HAVE_PETSC, test "x$petsc_libs" != "x" )

dnl parmetis
AC_CHECK_PARMETIS

dnl grace 
AC_CHECK_HEADERS([grace_np.h])
AC_CHECK_LIB([grace_np],GraceClose,[grace_libs="-lgrace_np"],[grace_libs=""])
AC_SUBST(grace_libs)


all_includes="-I\$(top_srcdir)/life/lifecore -I\$(top_srcdir)/life/lifearray  -I\$(top_srcdir)/life/lifemesh -I\$(top_srcdir)/life/lifealg  -I\$(top_srcdir)/life/lifefem -I\$(top_srcdir)/life/lifesolver -I\$(top_srcdir)/life/lifefilters"
AC_SUBST(all_includes)

CPPFLAGS="-DTHREEDIM ${CPPFLAGS}"

CXXFLAGS="-Wall ${CXXFLAGS}"


life_libs="\$(top_builddir)/life/lifefilters/liblifefilters.la \$(top_builddir)/life/lifesolver/liblifesolver.la  \$(top_builddir)/life/lifefem/liblifefem.la \$(top_builddir)/life/lifealg/liblifealg.la \$(top_builddir)/life/lifemesh/liblifemesh.la \$(top_builddir)/life/lifearray/liblifearray.la \$(top_builddir)/life/lifecore/liblifecore.la"

#life_libs="\$(top_builddir)/life/lifefilters/liblifefilters.la  \$(top_builddir)/life/lifesolver/liblifesolver.la \$(top_builddir)/life/lifefem/liblifefem.la \$(top_builddir)/life/lifealg/liblifealg.la \$(top_builddir)/life/lifemesh/liblifemesh.la \$(top_builddir)/life/lifearray/liblifearray.la \$(top_builddir)/life/lifecore/liblifecore.la"

#life_libs="\$(top_builddir)/life/lifefilters/liblifefilters.la  \$(top_builddir)/life/lifefem/liblifefem.la \$(top_builddir)/life/lifealg/liblifealg.la \$(top_builddir)/life/lifearray/liblifearray.la \$(top_builddir)/life/lifemesh/liblifemesh.la \$(top_builddir)/life/lifecore/liblifecore.la"

AC_SUBST(life_libs)


#
# setting prefix
#  
prefix=${prefix:-"/usr"}
if test "x${prefix}" = "xNONE"; then
    prefix=/usr
fi


dnl testdir
AC_CONFIG_TESTDIR(testsuite)